DIY-High-Quality-Barndoor / Astronachführung

/*
BYJ48 Stepper motor code
Connect :
IN1 >> D8
IN2 >> D9
IN3 >> D10
IN4 >> D11
VCC ... 5V Prefer to use external 5V Source
Gnd
written By :Mohannad Rawashdeh
http://www.instructables.com/member/Mohannad+Rawashdeh/
28/9/2013
*/

//This library allows you to communicate with I2C / TWI devices.
//uses SDA, SDL for OLED
#include <Wire.h>
//OLED Bibliotheken
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define OLED_RESET 4 // not used / nicht genutzt bei diesem Display
Adafruit_SSD1306 display(OLED_RESET);

//hier die Pinbelegung vom Nano zum Treiber eintragen, WICHTIG sie müssen aufeinander folgen, siehe writestep()
#define IN1 8
#define IN2 9
#define IN3 10
#define IN4 11
//Eingang Pin vom Auslöser
const int buttonPinEnd = 2;
int buttonStateEnd = 0; 
//maximal auszuführende Steps pro startbefehl          
long NBSTEPS = 16433;
//Übergabewert für die Wartezeit zwischen den Steps
long STEPTIME;
//Dies ist die Wartezeit in millis() zwischen den Einzelschritten, dient zur Anpassung der Nachführgeschwindigkeit
long FEEDTIME = 289500;
//Schnellrücklauf Wartezeit in millis ()
long BACKTIME = 1000;
//bekommt die Geschwindigkeitsrampe zum Herausfahren des Spiels beim Start
long rampstep;
//Abfragewert ob ausreichend millis() vergangen sind um einen Schritt weiter zu gehen  
unsigned long lastTime;
//index zum Durchtakten der 8 Schritte
int Step = 0;
//Drehrichtung vom Motor
boolean Clockwise = true;
//Die Arrays beinhalten die Schaltzustände der einzelnen Steps
int arrayDefault[4] = {LOW, LOW, LOW, LOW};
int stepsMatrix[8][4] = {
{LOW, LOW, LOW, HIGH},
{LOW, LOW, HIGH, HIGH},
{LOW, LOW, HIGH, LOW},
{LOW, HIGH, HIGH, LOW},
{LOW, HIGH, LOW, LOW},
{HIGH, HIGH, LOW, LOW},
{HIGH, LOW, LOW, LOW},
{HIGH, LOW, LOW, HIGH},
};

void setup() {
    // initialize with the I2C addr 0x3C / mit I2C-Adresse 0x3c initialisieren
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);

  //Motortreiber Ausgang initialisieren
  Serial.begin(9600);
  pinMode(IN1, OUTPUT); 
  pinMode(IN2, OUTPUT); 
  pinMode(IN3, OUTPUT); 
  pinMode(IN4, OUTPUT);

  // initialize the pushbutton pin as an input:
  pinMode(buttonPinEnd, INPUT);
  // internen Widerstand benutzen, es aendert sich das Schaltsignal beim Oeffner auf LOW als geschaltet
  digitalWrite(buttonPinEnd, HIGH);

  //Startbildschirm einmalig erzeugen
  display.clearDisplay();
  display.invertDisplay(false);
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(1,1);
  display.println(" - Startracker 1.2 - ");
  display.setTextSize(2);
  display.setCursor(22,25);
  display.println("STOPPED");
  display.setTextSize(1);
  display.setCursor(0,56);
  display.println("Geile Bilders machen!");
  display.display();
  delay(100);
}

void loop() {
  // read the state of the pushbutton value: delay zum Entprellen
  delay(100);
  buttonStateEnd = digitalRead(buttonPinEnd);
  if (buttonStateEnd == LOW) {
    delay(100); //nochmals entprellen
    buttonStateEnd = digitalRead(buttonPinEnd);
    if (buttonStateEnd == LOW) { //LOW = geschaltet
      for (int j=0;j < 20; j++){ //pruefen ob der Knopf gedrückt gehalten wird
        buttonStateEnd = digitalRead(buttonPinEnd);
        if (buttonStateEnd == LOW) {
          if (j == 19) { //Knopf wurde 20 Sekunden gedrückt gehalten, Rueckfahrtprogramm starten
            Clockwise = true;
            STEPTIME = BACKTIME; //zuweisen der Ruecklaufgeschwindigkeit
            delay(100);
            displayStatus(2); //Anzeige Rueckfahrt
            delay(1000);
            startengine(); //Motorbewegung starten
            break;
          }
          delay(100);
        }
        else {       
          delay (100);
          Clockwise = false; //vorwaerts
          STEPTIME = FEEDTIME; //Nachfuergeschwindigkeit zuweisen
          //Rampe berechnen
          rampstep = (FEEDTIME - FEEDTIME/100)/20;
          displayStatus(4);
          NBSTEPS = 100;
          STEPTIME = FEEDTIME/100;
          startengine();
          for (int k=0; k<20; k++){ //Rampe abfahren
            STEPTIME = FEEDTIME / 100 + k * rampstep;
            NBSTEPS = 1;
            startengine();          
          }
          //tracking starten
          delay(100);
          STEPTIME = FEEDTIME;
          //Display Nachfuehrung anzeigen
          displayStatus(1);
          NBSTEPS = 20000;
          startengine(); 
          break;
        }
      }
    }
  }
}


void startengine(){
  unsigned long currentMicros;
  long stepsLeft = NBSTEPS; //Maximalschrittzahl festlegen
  //so lange noch Schritte uebrig, fahre
  while(stepsLeft > 0){
    //aktuell Laufzeit speichern
    currentMicros = micros();
    //vergleichen mit der vergangenen Zeit seit dem letzten step, wenn limit erreich, abfahrt
    if(currentMicros - lastTime >= STEPTIME){
      //wird der Knopf gedrückt, wird angehalten
      buttonStateEnd = digitalRead(buttonPinEnd);
      if (buttonStateEnd == LOW) {
        delay(100);
        // Stop anzeigen
        displayStatus(3);
        delay (100);
        return;
      }
      stepper(); 
      lastTime = micros();
      stepsLeft--;
    }
  }
  stepsLeft = NBSTEPS;
}

//Schaltzustand fuer die Pins durchschalten
void writeStep(int outArray[4]){
  for (int i=0;i < 4; i++){
    digitalWrite(IN1 + i, outArray[i]);
  }
}

//Schaltzustand dem Schritt zuweisen
void stepper(){
  if ((Step >= 0) && (Step < 8)){
    writeStep(stepsMatrix[Step]);
  }else{
    writeStep(arrayDefault);
  }
  setDirection();
} 

//je nach Richtungswahl wird ein Schritt vorher oder spaeter aus dem array gesucht
void setDirection(){
  (Clockwise) ? (Step++) : (Step--);
  if(Step>7){
    Step=0;
  }else if(Step<0){
    Step=7; 
  }
}

//Anzeigen Switch
void displayStatus(int z){
  switch (z){
    //Nachführen
    case 1:
      display.clearDisplay();
      display.setTextColor(WHITE);
      display.setTextSize(1);
      display.setCursor(1,1);
      display.println(" - Startracker 1.2 - ");
      display.setTextSize(2);
      display.setCursor(15,17);
      display.println("tracking");
      display.setCursor(23,35);
      display.println("started");
      display.setTextSize(1);
      display.setCursor(14,56);
      display.print("steptime: ");
      display.println(STEPTIME);
      display.display();
    break;
    //schnellrücklauf
    case 2:
      display.clearDisplay();
      display.setTextColor(WHITE);
      display.setTextSize(1);
      display.setCursor(1,1);
      display.println(" - Startracker 1.2 - ");
      display.setTextSize(2);
      display.setCursor(25,25);
      display.println("rewind");
      display.setTextSize(1);
      display.setCursor(14,56);
      display.print("steptime: ");
      display.println(STEPTIME);
      display.display();
    break;
    //Motor stoppen
    case 3:
      display.clearDisplay();
      display.setTextColor(WHITE);
      display.setTextSize(1);
      display.setCursor(1,1);
      display.println(" - Startracker 1.2 - ");
      display.setTextSize(2);
      display.setCursor(22,25);
      display.println("STOPPED");
      display.setTextSize(1);
      display.setCursor(20,56);
      display.println("- RAUCHPAUSE! -");
      display.display();
    break;
    //ramp up
    case 4:
      display.clearDisplay();
      display.setTextColor(WHITE);
      display.setTextSize(1);
      display.setCursor(1,1);
      display.println(" - Startracker 1.2 - ");
      display.setTextSize(2);
      display.setCursor(22,25);
      display.println("RAMP UP");
      display.setTextSize(1);
      display.setCursor(20,56);
      display.println("- ruhig Blut! -");
      display.display();
    break;
  }
}